next up previous contents
Next: Datei beispiel.log' Up: Beispiel Previous: Ergebnisse

   
Datei beispiel.bat'

@ECHO OFF
ECHO ======================================================================
ECHO Beispiel zum Programmpaket WAVE
ECHO ======================================================================

REM -----------------------------------------------------------------------
REM pruefen der Einstellungen
if not exist beispiel.asc goto NO_INPUT
if "%WAVEDIR%"=="" goto NO_WAVE
if not exist %WAVEDIR%pink.exe     goto NO_PGM
if not exist %WAVEDIR%import.exe   goto NO_PGM
if not exist %WAVEDIR%filter.exe   goto NO_PGM
if not exist %WAVEDIR%noise.exe    goto NO_PGM
if not exist %WAVEDIR%add_wave.exe goto NO_PGM
if not exist %WAVEDIR%pwr_spec.exe goto NO_PGM
if not exist %WAVEDIR%bandsum.exe  goto NO_PGM
if not exist %WAVEDIR%xcorr.exe    goto NO_PGM
if not exist %WAVEDIR%optfilt.exe  goto NO_PGM
if not exist %WAVEDIR%add_info.exe goto NO_PGM
if not exist %WAVEDIR%plotwave.exe goto NO_PGM
if not exist %WAVEDIR%plotspec.exe goto NO_PGM
if not exist %WAVEDIR%plotcorr.exe goto NO_PGM
if not exist %WAVEDIR%plotfilt.exe goto NO_PGM
goto WAVE_OK

:NO_INPUT
ECHO ACHTUNG: Das für das Beispiel benötigte ASCII-File 'beispiel.asc'
ECHO konnte nicht gefunden werden!
GOTO ENDE

:NO_WAVE
ECHO ACHTUNG: Die Environment-Variable zum Auffinden der WAVE-Utilities
ECHO ist nicht gesetzt!
GOTO WAVE_ERR

:NO_PGM
ECHO ACHTUNG: Die fuer das Beispiel benoetigten Programme konnten nicht
ECHO gefunden werden. Eventuell ist die Environment-Variable WAVEDIR nicht
ECHO oder nicht richtig gesetzt.
GOTO WAVE_ERR

:WAVE_ERR
ECHO Bitte setzen Sie die Environment-Variable WAVEDIR entsprechend dem
ECHO folgenden Beispiel und starten Sie das Beispiel erneut.
ECHO   SET WAVEDIR=c:\tools\wave.021\
goto ENDE
:WAVE_OK

if not "%GRX20DRV%"=="" goto GRX_OK
ECHO ACHTUNG: Environment-Variable fuer Grafikausgabe nicht gesetzt!
ECHO bitte setzen sie die entsprechenden Werte entsprechend dem folgenden
ECHO Beispiel und starten Sie das Beispiel erneut.
ECHO   SET GRX20DRV=vesa gw 640 gh 480 nc 256
GOTO ENDE
:GRX_OK

ECHO ======================================================================
ECHO Berechnung der Signale und Spektren

ECHO ----------------------------------------------------------------------
ECHO Generierung von 1 Sekunde rosa Rauschen als Quellsequenz source.wav:
ECHO   %WAVEDIR%pink -L1 -r-20 -db120 source.wav
PAUSE
%WAVEDIR%pink -L1 -r-20 -db120 source.wav
%WAVEDIR%add_info "Quellsignal" source.wav


ECHO ----------------------------------------------------------------------
ECHO Import von Filterkoeffizienten aus der ASCII-Datei beispiel.asc
ECHO als FIR-Filter beispiel.flt:
ECHO   %WAVEDIR%import -ascii beispiel.asc beispiel.flt
PAUSE
%WAVEDIR%import -ascii beispiel.asc beispiel.flt
%WAVEDIR%add_info "Importiertes Filter" beispiel.flt

ECHO ----------------------------------------------------------------------
ECHO Filterung des rosa Rauschens mit dem FIR-Filter beispiel.flt:
ECHO   %WAVEDIR%filter source.wav beispiel.flt filter.wav
PAUSE
%WAVEDIR%filter source.wav beispiel.flt filter.wav
%WAVEDIR%add_info "Ausgangssignal des Filters" filter.wav

ECHO ----------------------------------------------------------------------
ECHO Addition von weissem Rauschen am Ausgang des FIR-Filters:
ECHO   %WAVEDIR%noise -L1 -r-20 -db60 noise.wav
ECHO   %WAVEDIR%add_wave filter.wav noise.wav out.wav
PAUSE
%WAVEDIR%noise -L1 -r-20 -db60 noise.wav
%WAVEDIR%add_info "Additives Rauschen am Ausgang des FIR-Filters" noise.wav
%WAVEDIR%add_wave filter.wav noise.wav out.wav
%WAVEDIR%add_info "Ausgangssignal der Strecke" out.wav

ECHO ----------------------------------------------------------------------
ECHO Berechnung der Spektren am Eingang und Ausgang der Strecke
ECHO als Schmalband-, Terzband- und Oktavbandanalyse:
ECHO   %WAVEDIR%pwr_spec source.wav out.wav -c4096 -all
ECHO   %WAVEDIR%bandsum -terz source.psd
ECHO   %WAVEDIR%bandsum -terz out.psd
ECHO   %WAVEDIR%pwr_spec noise.wav -c4096
ECHO   %WAVEDIR%bandsum -terz noise.psd
PAUSE
%WAVEDIR%pwr_spec source.wav out.wav -c4096 -all
%WAVEDIR%add_info "Spektrum am Eingang des Filters" source.psd
%WAVEDIR%add_info "Spektrum am Ausgang der Strecke" out.psd
%WAVEDIR%add_info "Kreuzleistungsdichte Eingang/Ausgang" out.csd
%WAVEDIR%bandsum -terz source.psd
%WAVEDIR%add_info "Terzbandspektrum am Eingang des Filters" source.pst
%WAVEDIR%bandsum -terz out.psd
%WAVEDIR%add_info "Terzbandspektrum am Ausgang der Strecke" out.pst
%WAVEDIR%pwr_spec noise.wav -c4096
%WAVEDIR%add_info "Spektrum des additiven Rauschens" noise.psd
%WAVEDIR%bandsum -terz noise.psd
%WAVEDIR%add_info "Terzbandspektrum des additiven Rauschens" noise.pst

ECHO ----------------------------------------------------------------------
ECHO Berechnung der Auto- und Kreuzkorrelation
ECHO von Eingang und Ausgang der Strecke:
ECHO   %WAVEDIR%xcorr source.wav out.wav -c128
PAUSE
%WAVEDIR%xcorr source.wav out.wav -c128
%WAVEDIR%add_info "Autokorrelation des Quellsignales" source.acf
%WAVEDIR%add_info "Autokorrelation des Ausgangssignales der Strecke" out.acf
%WAVEDIR%add_info "Kreuzkorrelation Eingangs/Ausgang" out.xcf

ECHO ----------------------------------------------------------------------
ECHO Berechnung des optimalen Filters aus Auto- und Kreuzkorrelation:
ECHO   %WAVEDIR%optfilt source.acf out.xcf -fir -len64 estimate.flt
PAUSE
%WAVEDIR%optfilt source.acf out.xcf -fir -len64 estimate.flt
%WAVEDIR%add_info "berechnete Impulsantwort" estimate.flt

ECHO ======================================================================
ECHO Grafische Darstellung der Ergebnisse

ECHO ----------------------------------------------------------------------
ECHO Darstellung der Zeitverlaeufe der ersten 1/100 Sekunde:
ECHO   %WAVEDIR%plotwave source.wav out.wav -L0.01 -grid
PAUSE
%WAVEDIR%plotwave source.wav out.wav -L0.01 -grid

ECHO ----------------------------------------------------------------------
ECHO Darstellung der Spektren und der Kohaerenz:
ECHO   %WAVEDIR%plotspec source.psd out.psd out.csd -c -grid
PAUSE
%WAVEDIR%plotspec source.psd out.psd out.csd -c -grid

ECHO ----------------------------------------------------------------------
ECHO Darstellung der Terzbandspektren:
ECHO   %WAVEDIR%plotspec source.pst noise.pst out.pst -flog -grid
PAUSE
%WAVEDIR%plotspec source.pst noise.pst out.pst -flog -grid

ECHO ----------------------------------------------------------------------
ECHO Darstellung der Auto- und Kreuzkorrelation:
ECHO   %WAVEDIR%plotcorr source.acf out.acf out.xcf -grid
PAUSE
%WAVEDIR%plotcorr source.acf out.acf out.xcf -grid

ECHO ----------------------------------------------------------------------
ECHO Darstellung der Impulsantwort des verwendeten Filters und der aus
ECHO Auto- und Kreuzkorrelation errechneten Impulsantwort der Strecke:
ECHO   %WAVEDIR%plotfilt beispiel.flt estimate.flt -min-0.02 -max0.1
PAUSE
%WAVEDIR%plotfilt estimate.flt beispiel.flt -min-0.02 -max0.1

ECHO ======================================================================
ECHO Erstellen der Datei 'FILEINFO.TXT' mit Information über alle
ECHO generierten Dateien
%WAVEDIR%fileinfo source.wav filter.wav noise.wav out.wav -q > beispiel.log
%WAVEDIR%fileinfo source.ps[dt] noise.ps[dt] -q >> beispiel.log
%WAVEDIR%fileinfo out.ps[dt] out.csd -q >> beispiel.log
%WAVEDIR%fileinfo source.acf out.[ax]cf -q >> beispiel.log
%WAVEDIR%fileinfo beispiel.flt estimate.flt -q >> beispiel.log


ECHO ======================================================================
ECHO Ende des Beispiels zum Programmpaket WAVE
ECHO ======================================================================
:ENDE



root
1998-07-09